カスタムグラフィックス

  class CCanvas

  #include <CanvasCanvas.mqh>

  class CChartCanvas : public CCanvas

  #include <CanvasChartsChartCanvas.mqh>

  class CHistogramChart : public CChartCanvas

  #include <CanvasChartsHistogramChart.mqh>

//+——————————————————————+
//|                                         HistogramChartSample.mq5 |
//|                   Copyright 2009-2017, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+——————————————————————+
#property copyright   "2009-2017, MetaQuotes Software Corp."
#property link       "http://www.mql5.com"
#property description "Example of using histogram"
//—
#include <CanvasChartsHistogramChart.mqh>
//+——————————————————————+
//| inputs                                                           |
//+——————————————————————+
input bool Accumulative=true;
//+——————————————————————+
//| Script program start function                                    |
//+——————————————————————+
int OnStart(void)
 {
  int k=100;
  double arr[10];
//— チャートを作成する
  CHistogramChart chart;
  if(!chart.CreateBitmapLabel("SampleHistogramChart",10,10,600,450))
    {
    Print("Error creating histogram chart: ",GetLastError());
    return(-1);
    }
  if(Accumulative)
    {
     chart.Accumulative();
     chart.VScaleParams(20*k*10,-10*k*10,20);
    }
  else
     chart.VScaleParams(20*k,-10*k,20);
  chart.ShowValue(true);
  chart.ShowScaleTop(false);
  chart.ShowScaleBottom(false);
  chart.ShowScaleRight(false);
  chart.ShowLegend();
  for(int j=0;j<5;j++)
    {
    for(int i=0;i<10;i++)
       {
        k=-k;
        if(k>0)
           arr[i]=k*(i+10-j);
        else
           arr[i]=k*(i+10-j)/2;
       }
     chart.SeriesAdd(arr,"Item"+IntegerToString(j));
    }
//— play with values
  while(!IsStopped())
    {
    int i=rand()%5;
    int j=rand()%10;
     k=rand()%3000-1000;
     chart.ValueUpdate(i,j,k);
    Sleep(200);
    }
//— finish
  chart.Destroy();
  return(0);
 }

  class CLineChart : public CChartCanvas

  #include <CanvasChartsLineChart.mqh>

//+——————————————————————+
//|                                              LineChartSample.mq5 |
//|                   Copyright 2009-2017, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+——————————————————————+
#property copyright   "2009-2017, MetaQuotes Software Corp."
#property link       "http://www.mql5.com"
#property description "Example of using line chart"
//—
#include <CanvasChartsLineChart.mqh>
//+——————————————————————+
//| inputs                                                           |
//+——————————————————————+
input bool Accumulative=false;
//+——————————————————————+
//| Script program start function                                    |
//+——————————————————————+
int OnStart(void)
 {
  int k=100;
  double arr[10];
//— チャートを作成する
  CLineChart chart;
//— create chart
  if(!chart.CreateBitmapLabel("SampleHistogrammChart",10,10,600,450))
    {
    Print("Error creating line chart: ",GetLastError());
    return(-1);
    }
  if(Accumulative)
    {
     chart.Accumulative();
     chart.VScaleParams(20*k*10,-10*k*10,20);
    }
  else
     chart.VScaleParams(20*k,-10*k,15);
  chart.ShowScaleTop(false);
  chart.ShowScaleRight(false);
  chart.ShowLegend();
  chart.Filled();
  for(int j=0;j<5;j++)
    {
    for(int i=0;i<10;i++)
       {
        k=-k;
        if(k>0)
           arr[i]=k*(i+10-j);
        else
           arr[i]=k*(i+10-j)/2;
       }
     chart.SeriesAdd(arr,"Item"+IntegerToString(j));
    }
//— play with values
  while(!IsStopped())
    {
    int i=rand()%5;
    int j=rand()%10;
     k=rand()%3000-1000;
     chart.ValueUpdate(i,j,k);
    Sleep(200);
    }
//— finish
  chart.Destroy();
  return(0);
 }

  class CPieChart : public CChartCanvas

  #include <CanvasChartsPieChart.mqh>

//+——————————————————————+
//|                                               PieChartSample.mq5 |
//|                   Copyright 2009-2017, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+——————————————————————+
#property copyright   "2009-2017, MetaQuotes Software Corp."
#property link       "http://www.mql5.com"
#property description "Example of using pie chart"
//—
#include <CanvasChartsPieChart.mqh>
//+——————————————————————+
//| 入力                                                              |
//+——————————————————————+
input int      Width=600;
input int      Height=450;
//+——————————————————————+
//| スクリプトプログラム開始関数                                              |
//+——————————————————————+
int OnStart(void)
 {
//— 確認
  if(Width<=0 || Height<=0)
    {
    Print("Too simple.");
    return(-1);
    }
//— チャートを作成する
  CPieChart pie_chart;
  if(!pie_chart.CreateBitmapLabel("PieChart",10,10,Width,Height))
    {
    Print("Error creating pie chart: ",GetLastError());
    return(-1);
    }
  pie_chart.ShowPercent();
//— 描画する
  for(uint i=0;i<30;i++)
    {
     pie_chart.ValueAdd(100*(i+1),"Item "+IntegerToString(i));
    Sleep(10);
    }
  Sleep(2000);
//— 凡例を無効にする
  pie_chart.LegendAlignment(ALIGNMENT_LEFT);
  Sleep(2000);
//— 凡例を無効にする
  pie_chart.LegendAlignment(ALIGNMENT_RIGHT);
  Sleep(2000);
//— 凡例を無効にする
  pie_chart.LegendAlignment(ALIGNMENT_TOP);
  Sleep(2000);
//— 凡例を無効にする
  pie_chart.ShowLegend(false);
  Sleep(2000);
//— パーセンテージを無効にする
  pie_chart.ShowPercent(false);
  Sleep(2000);
//— 記述子を無効にする
  pie_chart.ShowDescriptors(false);
  Sleep(2000);
//— 全てを有効にする
  pie_chart.ShowLegend();
  pie_chart.ShowValue();
  pie_chart.ShowDescriptors();
  Sleep(2000);
//— またはこのように
  pie_chart.ShowFlags(FLAG_SHOW_LEGEND|FLAG_SHOW_DESCRIPTORS|FLAG_SHOW_PERCENT);
  uint total=pie_chart.DataTotal();
//— 値と遊ぶ
  for(uint i=0;i<total && !IsStopped();i++)
    {
     pie_chart.ValueUpdate(i,100*(rand()%10+1));
    Sleep(1000);
    }
//— 色と遊ぶ
  for(uint i=0;i<total && !IsStopped();i++)
    {
     pie_chart.ColorUpdate(i%total,RandomRGB());
    Sleep(1000);
    }
//— 回転する
  while(!IsStopped())
    {
     pie_chart.DataOffset(pie_chart.DataOffset()+1);
    Sleep(200);
    }
//— 終わる
  pie_chart.Destroy();
  return(0);
 }
//+——————————————————————+
//| ランダムなRGB色                                                      |
//+——————————————————————+
uint RandomRGB(void)
 {
  return(XRGB(rand()%255,rand()%255,rand()%255));
 }